cmd IP 변경 배치파일

 

• 배치 파일 인코딩은 ANSI로 설정 
• %SYSTEMROOT%\System32 위치에 복사 
• cmd에서 ip 혹은 ip.bat 를 입력하여 실행
  o IP 수동 설정은 1, DHCP 설정은 2 입력 후 엔터
  o IP를 변경할 NIC 색인 번호 선택
  o IP와 GATEWAY 설정, Subnet은 255.255.255.0(24)로 자동 구성
  o 설정 완료 시 갱신된 IP가 조회됨 
  

@echo off
if not "%1"=="am_admin" (powershell start -verb runas '%0' am_admin & exit /b) 

:: 한글 변환, 인코딩 변환 명령 % -> !
chcp 65001 > nul
setlocal enabledelayedexpansion

:INPUT
echo.
echo "IP 변경 - 수동(1), dhcp(2)"
set /p select= :
 
if %select% == 1 (
echo.
echo.
netsh interface ip show interfaces
echo.
echo.
set /p NIC=설정하려는 장치의 색인 번호	: 

echo.
netsh interface ip show config !NIC! | findstr "Configuration"
netsh interface ip show config !NIC! | findstr "IP"
netsh interface ip show config !NIC! | findstr "Subnet"
netsh interface ip show config !NIC! | findstr "Default"
echo.

set /p IP=IP Address			: 
set /p GATEWAY=GATEWAY				: 
netsh interface ipv4 set address !NIC! static !IP! 255.255.255.0 !GATEWAY!

echo wait..
timeout 4 > NUL
netsh interface ip show config !NIC! | findstr "interface"
netsh interface ip show config !NIC! | findstr "IP"
netsh interface ip show config !NIC! | findstr "Subnet"
netsh interface ip show config !NIC! | findstr "Default"
echo.

) else if %select% == 2 (

echo.
echo.
netsh interface ip show interfaces
echo.
echo.
set /p NIC=설정하려는 장치의 색인 번호	: 

netsh interface ipv4 set address name=!NIC! source=dhcp

echo wait..
timeout 4 > NUL
netsh interface ip show config !NIC! | findstr "interface"
netsh interface ip show config !NIC! | findstr /C:"DHCP enabled"
netsh interface ip show config !NIC! | findstr "IP"
netsh interface ip show config !NIC! | findstr "Subnet"
netsh interface ip show config !NIC! | findstr "Default"
)

echo.
set /p que=다시 설정하시겠습니까? y,n 
if "%que%" equ "y" (goto INPUT)

ip.bat

0.00MB