원격 데스크톱 포트 변경(수동,자동)

ி 레지스트리 편집

➽ 실행창[win+R] > regedit

HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp
PortNumber를 더블클릭 해서 편집한 뒤 10진수에 체크하고 3389 대신 변경할 포트번호를 입력한다.

ி 방화벽 포트 추가

➽ 실행창 > wf.msc > 인바운드 규칙 > 새 규칙

ி 원격 데스크톱 서비스 재시작

서비스를 재시작 해야 변경된 포트가 적용된다. 
➽ 실행창 > services.msc > Remote Desktop Services > 다시 시작

ி 원격 접속

➽ 실행창 > mstsc > ip:변경된 포트입력

ி 스크립트로 자동 변경

1번 메뉴를 선택하여 원격 포트를 바꿀 수 있다.
3번 메뉴를 통해 방화벽에 추가된 포트 값을 조회한다.
2번 메뉴에서는 불 필요한 포트나 잘 못 입력한 포트를 입력하여 삭제한다.

레지스트리에 있는 값이 아닌 , 방화벽 정책만 삭제한다. 

 아래 배치 파일을 다운받고 우클릭하여 관리자 권한으로 실행한다.

RDP 포트 변경.bat

 

@echo off
 
bcdedit > nul || (echo 우클릭 하여 관리자 권한으로 실행하세요. & pause & exit)
 
 
:INPUT
cls
echo 1. 원격 데스크톱 포트(3389)를 변경합니다.
echo 2. 변경한 원격 데스크톱 포트를 지웁니다.
echo 3. 설정한 원격 데스크톱 목록을 확인합니다.
echo 4. 종료
 
set /p select=메뉴 선택(1,2,3,4) :
cls
 
if %select% == 1 ( 
set /p port=변경 할 포트 번호 입력 : 
) else if %select% == 2 ( 
set /p del_port=제거할 원격 데스크톱 포트 번호 입력 : 
) else if %select% == 3 ( 
netsh advfirewall firewall show rule name=all dir=in | findstr /C:"원격 데스크톱" 
) else if %select% == 4 ( exit ) else ( goto INPUT )
 
if %select% == 1 (
 
if "%port%" == "" (
goto INPUT
)
 
reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d 0 /f
reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v PortNumber /t REG_DWORD /d %port% /f
 
netsh advfirewall firewall add rule name="원격 데스크톱 %port%" description="3389포트 대신 %port%를 사용합니다." dir=in action=allow protocol=tcp localport=%port%
net stop /y TermService
net start /y TermService
 
echo 포트가 %port%로 변경되었습니다.
) else if %select% == 2 ( 
 
if "%del_port%" == "" (
goto INPUT
)
netsh advfirewall firewall delete rule name="원격 데스크톱 %del_port%" dir=in protocol=tcp localport=%del_port%
)
 
echo.
echo 계속하려면 Any 키를 누르세요.
pause > nul
goto INPUT